Skocz do zawartości

IzyboT

ProeXtreme

Przez ProeXtreme,
w Projekty - DIY roboty

 Udostępnij

Pomocna odpowiedź

  • Popularny post
ProeXtreme Stały bywalec

ProeXtreme

Napisano
  • Popularny post
Napisano

Nadszedł czas na opis IzyboT'a - robota, którego koncept został stworzony w 2009 roku. Podstawą do zbudowania tego robota było podwozie jeżdżącego robota, zakupionego przez Zespół Szkół Mechanicznych w Opolu. Płytka PCB w całości została przeze mnie zaprojektowana i wykonana metodą termotransferu.

Celem stworzenia robota był start w pierwszej edycji zawodów Follow The Line w Rybniku w 2009r. Robot świetnie się spisywał na trasie testowej. Niestety w czasie pierwszego przejazdu robot zamiast skręcić pojechał prosto. Jak się niedawno okazało, przyczyną takiego zachowania były kiepskie luty.

Robot niedawno został reaktywowany, czego wynikiem był start w zawodach Robotic Tournament w Rybniku. Przez trzy lata IzyboT stał na półce i czekając na start w zawodach. Jak widać doczekał się! Zamieszczam wszystkie informacje dotyczące tego robota, aby pomóc początkującym w stworzeniu swojej pierwszej konstrukcji.

Koncept: 2009

Elektronika

  • Procesor: ATmega16
  • Kwarc: 16MHz
  • Motor driver: L293D
  • Wyświetlacz: LCD 2*16
  • Ilość czujników: 6 (CNY70)
  • Zasilanie: 10 akumulatorków NiMH (na zawodach Robotic Tournament 2012 był pakiet Li-Po 800mAh)
  • Inne:Przełącznik prędkości, wyłącznik zbędnego obciążenia, trzy LED, dwustronna PCB

Mechanika

  • Silniki: 20GA2025-08530-25 12V 230RPM
  • Konstrukcja: Zielone plexi + metalowe dystanse + kółko od krzesła obrotowego

Program

  • Język programowania: BASCOM

Poniżej znajduje się kompletny program, który sterował robotem na zawodach Robotic Tournament 2012.

'-------------------------------------------------------------------------------
'Author:           Piotr Śnieżek
'Nick:             ProeXtreme
'E-mail:           ProeXtreme@o2.pl
'Date:             23-03-2012
'-------------------------------------------------------------------------------

$regfile = "m16def.dat"                                     'Mikrokontroler to ATmega16
$crystal = 16000000                                         'Kwarc 16MHz
'-------------------------------------------------------------------------------
'Konfiguracja typu i pinów wyświatlacz LCD
'-------------------------------------------------------------------------------
Config Lcd = 16 * 2                                         'Wykorzystywany wyświetlacz jest organizacji 16 *2
Config Lcdpin = Pin , Db4 = Porta.3 , Db5 = Porta.2 , Db6 = Porta.1 , Db7 = Porta.0 , E = Porta.4 , Rs = Porta.5       'Konfiguracja pinów wyświetlacza
'-------------------------------------------------------------------------------
'Konfiguracja PWM
'-------------------------------------------------------------------------------
Config Timer1 = Pwm , Pwm = 8 , Compare A Pwm = Clear Down , Compare B Pwm = Clear Down , Prescale = 8

'-------------------------------------------------------------------------------
'Konfiguracja pinów
'-------------------------------------------------------------------------------
Config Pina.6 = Input                                       'Przełącznik prędkości (1)
Config Pina.7 = Input                                       'Przełącznik prędkości (2)
Config Pinb.2 = Input                                       'Przełącznik prędkości (3)
Config Pinb.3 = Input                                       'Przycisk START
Config Pinb.4 = Input                                       'Przycisk STOP
Config Portd.0 = Output                                     'Dioda gotowość (zielona)
Config Portd.1 = Output                                     'Dioda ustawienia (żółta)
'Czujniki
Config Pinb.1 = Input                                       'Czujnik 1
Config Pinb.0 = Input                                       'Czujnik 2
Config Pinc.7 = Input                                       'Czujnik 3
Config Pinc.6 = Input                                       'Czujnik 4
Config Pinc.1 = Input                                       'Czujnik 5
Config Pinc.0 = Input                                       'Czujnik 6
'Motor driver
Config Portd.6 = Output                                     ' 1A
Config Portd.7 = Output                                     ' 2A
Config Portd.3 = Output                                     ' 3A
Config Portd.2 = Output                                     ' 4A
'-------------------------------------------------------------------------------
'Aliasy
'-------------------------------------------------------------------------------
Speed_button_1 Alias Pina.6
Speed_button_1_port Alias Porta.6
Speed_button_2 Alias Pina.7
Speed_button_2_port Alias Porta.7
Speed_button_3 Alias Pinb.2
Speed_button_3_port Alias Portb.2
Start_button Alias Pinb.3                                   'Przycisk START
Start_button_port Alias Portb.3
Stop_button Alias Pinb.4                                    'Przycisk STOP
Stop_button_port Alias Portb.4
Set Speed_button_1_port
Set Speed_button_2_port
Set Speed_button_3_port

Led_ready Alias Portd.0                                     'Dioda gotowość (zielona)
Led_settings Alias Portd.1                                  'Dioda ustawienia (żółta)

Set Start_button_port
Set Stop_button_port

Left_motor_przod Alias Portd.6
Left_motor_tyl Alias Portd.7
Right_motor_przod Alias Portd.2
Right_motor_tyl Alias Portd.3
'Czujniki
Cz1 Alias Pinb.1                                            'Czujnik 1
Cz2 Alias Pinb.0                                            'Czujnik 2
Cz3 Alias Pinc.7                                            'Czujnik 3
Cz4 Alias Pinc.6                                            'Czujnik 4
Cz5 Alias Pinc.1                                            'Czujnik 5
Cz6 Alias Pinc.0                                            'Czujnik 6
'-------------------------------------------------------------------------------
'Konfiguracja zmiennych
'-------------------------------------------------------------------------------
Dim Name_of_software As String * 17                         'Nazwa wgranego programu
Dim Version_of_software As String * 5                       'Wersja wgranego programu
Dim Linia As Bit
Dim Tlo As Bit
Dim Wcisniety As Bit
Dim Puszczony As Bit
Dim Max_speed As Byte                                       'Maksymalne wypełnienie silników PWM
Dim Jedzie As Bit
Dim Stoi As Bit
Dim Zakret As Byte
Dim Ostry_zakret As Byte
Dim Przodskret As Byte
Dim Licznik_czasu As Byte
Dim Lewy_ostatni As Bit
Dim Prawy_ostatni As Bit
Dim Lewy_ostry_ostatni As Bit
Dim Prawy_ostry_ostatni As Bit
Dim Skret_p(6) As Byte
Dim Skret_l(6) As Byte
'-------------------------------------------------------------------------------
'Ustawienia wstępne
'-------------------------------------------------------------------------------
Name_of_software = "IzyboT  2012"
Version_of_software = "v1.09"
Cursor Off                                                  'Wyłącza kursor
Led_ready = 1                                               '0-wygaszenie diody, 1-zaświecenie diody
Led_settings = 1
Linia = 1
Tlo = 0
Wcisniety = 0
Puszczony = 1
Jedzie = 1
Stoi = 0
Left_motor_przod = Stoi
Left_motor_tyl = Stoi
Right_motor_przod = Stoi
Right_motor_tyl = Stoi
Licznik_czasu = 0
'-------------------------------------------------------------------------------
'Program główny
'-------------------------------------------------------------------------------
Cls                                                         'Czyści ekran
Locate 1 , 3
Lcd Name_of_software
Locate 2 , 7
Lcd Version_of_software
Wait 1
Cls
Gosub Sensors_settings
Cls
Do
  Gosub Speed_settings
  Do
     Left_motor_przod = Jedzie                             'Przy rozpoczęciu jazdy robot będzie jeździł do przodu
     Right_motor_przod = Jedzie

     If Cz1 = Linia Then                                   'Przygotowanie do ostrego skretu w lewo
        Lewy_ostry_ostatni = 1
     End If
     If Cz6 = Linia Then                                   'Przygotowanie do ostrego skretu w prawo
        Prawy_ostry_ostatni = 1
     End If

'...............................................................................
'Jazda na wprost
'...............................................................................
     If Cz1 = Tlo And Cz2 = Tlo And Cz3 = Linia And Cz4 = Linia And Cz5 = Tlo And Cz6 = Tlo Then Gosub Prosto       '4,5
'...............................................................................
'Skręt w prawo
'...............................................................................
     If Cz1 = Tlo And Cz2 = Tlo And Cz3 = Tlo And Cz4 = Tlo And Cz5 = Linia And Cz6 = Tlo Then Gosub Lekko_w_prawo       '5
     If Cz1 = Tlo And Cz2 = Tlo And Cz3 = Linia And Cz4 = Tlo And Cz5 = Linia And Cz6 = Tlo Then Gosub Lekko_w_prawo       '3,5
     If Cz1 = Tlo And Cz2 = Tlo And Cz3 = Tlo And Cz4 = Linia And Cz5 = Linia And Cz6 = Tlo Then Gosub Lekko_w_prawo       '4,5
     If Cz1 = Tlo And Cz2 = Tlo And Cz3 = Linia And Cz4 = Linia And Cz5 = Linia And Cz6 = Tlo Then Gosub Lekko_w_prawo       '3,4,5
     If Cz1 = Linia And Cz2 = Linia And Cz3 = Tlo And Cz4 = Tlo And Cz5 = Tlo And Cz6 = Tlo Then Gosub Lekko_w_prawo       '1,2

     If Cz1 = Tlo And Cz2 = Tlo And Cz3 = Tlo And Cz4 = Tlo And Cz5 = Tlo And Cz6 = Linia Then Gosub Ostro_w_prawo       '6

     If Cz1 = Tlo And Cz2 = Tlo And Cz3 = Tlo And Cz4 = Linia And Cz5 = Tlo And Cz6 = Linia Then Gosub Zawracanie_w_prawo       '4,6
'...............................................................................
'Skręt w lewo
'...............................................................................
     If Cz1 = Tlo And Cz2 = Linia And Cz3 = Tlo And Cz4 = Tlo And Cz5 = Tlo And Cz6 = Tlo Then Gosub Lekko_w_lewo       '2
     If Cz1 = Tlo And Cz2 = Linia And Cz3 = Linia And Cz4 = Tlo And Cz5 = Tlo And Cz6 = Tlo Then Gosub Lekko_w_lewo       '2,3
     If Cz1 = Tlo And Cz2 = Linia And Cz3 = Tlo And Cz4 = Linia And Cz5 = Tlo And Cz6 = Tlo Then Gosub Lekko_w_lewo       '2,4
     If Cz1 = Tlo And Cz2 = Linia And Cz3 = Linia And Cz4 = Linia And Cz5 = Tlo And Cz6 = Tlo Then Gosub Lekko_w_lewo       '2,3,4
     If Cz1 = Tlo And Cz2 = Tlo And Cz3 = Tlo And Cz4 = Tlo And Cz5 = Linia And Cz6 = Linia Then Gosub Lekko_w_lewo       '5,6

     If Cz1 = Linia And Cz2 = Tlo And Cz3 = Tlo And Cz4 = Tlo And Cz5 = Tlo And Cz6 = Tlo Then Gosub Ostro_w_lewo       '1

     If Cz1 = Linia And Cz2 = Tlo And Cz3 = Tlo And Cz4 = Linia And Cz5 = Tlo And Cz6 = Tlo Then Gosub Zawracanie_w_lewo       '1,4
'...............................................................................
'Skrzyżowanie
'...............................................................................
     If Cz2 = Linia And Cz3 = Linia And Cz5 = Linia Then Gosub Prosto       '2,3,5
'...............................................................................
'Kierunek jazdy nie określony
'...............................................................................

     If Cz1 = Tlo And Cz2 = Tlo And Cz3 = Tlo And Cz4 = Linia And Cz5 = Tlo And Cz6 = Tlo Then

        If Prawy_ostatni = 1 Or Prawy_ostry_ostatni = 1 Then
           Pwm1a = Max_speed
           Pwm1b = Max_speed
           Right_motor_przod = Stoi
           Waitms 15
           Right_motor_tyl = Jedzie
           Do
           Loop Until Cz3 = Linia Or Cz2 = Linia
           Right_motor_tyl = Stoi
           Waitms 15
           Right_motor_przod = Jedzie
           Prawy_ostry_ostatni = 0
           Lewy_ostry_ostatni = 0
        End If
        If Lewy_ostatni = 1 Or Lewy_ostry_ostatni = 1 Then
           Pwm1a = Max_speed
           Pwm1b = Max_speed
           Left_motor_przod = Stoi
           Waitms 15
           Left_motor_tyl = Jedzie
           Do
           Loop Until Cz3 = Linia Or Cz2 = Linia
           Left_motor_tyl = Stoi
           Waitms 15
           Left_motor_przod = Jedzie
           Prawy_ostry_ostatni = 0
           Lewy_ostry_ostatni = 0
        End If
     End If
'Powrót na linię po wyjechaniu za nią
     If Cz1 = Tlo And Cz2 = Tlo And Cz3 = Tlo And Cz4 = Tlo And Cz5 = Tlo And Cz6 = Tlo Then
        If Prawy_ostatni = 1 Then
           Pwm1a = Max_speed
           Pwm1b = Zakret
        End If
        If Prawy_ostry_ostatni = 1 Then
           Pwm1a = Max_speed
           Pwm1b = Max_speed
           Right_motor_przod = Stoi
           Waitms 15
           Right_motor_tyl = Jedzie
           Do
           Loop Until Cz3 = Linia Or Cz2 = Linia
           Right_motor_tyl = Stoi
           Waitms 15
           Right_motor_przod = Jedzie
           Prawy_ostry_ostatni = 0
           Lewy_ostry_ostatni = 0
        End If

        If Lewy_ostatni = 1 Then
           Pwm1a = Zakret
           Pwm1b = Max_speed
        End If
        If Lewy_ostry_ostatni = 1 Then
           Pwm1a = Max_speed
           Pwm1b = Max_speed
           Left_motor_przod = Stoi
           Waitms 15
           Left_motor_tyl = Jedzie
           Do
           Loop Until Cz3 = Linia Or Cz2 = Linia
           Left_motor_tyl = Stoi
           Waitms 15
           Left_motor_przod = Jedzie
           Prawy_ostry_ostatni = 0
           Lewy_ostry_ostatni = 0
        End If
     End If

'...............................................................................
'Przyciski ustawień prędkości
'...............................................................................

     If Start_button = Wcisniety Then
        Cls
        Lcd "Zakret PWM: "
        Do
        Loop Until Start_button = Puszczony
        Do
           Locate 1 , 13
           Lcd Zakret ; " "
           If Cz5 = Linia Then
              Pwm1a = Max_speed
              Pwm1b = Zakret
           End If
           If Cz2 = Linia Then
              Pwm1a = Zakret
              Pwm1b = Max_speed
           End If


           Licznik_czasu = 0
           Led_settings = 0
           While Start_button = Wcisniety
              Do
                 Waitms 10
                 Incr Licznik_czasu
                 If Licznik_czasu = 100 Then Led_settings = 1
              Loop Until Start_button = Puszczony
              If Led_settings = 1 Then Exit Do
              If Licznik_czasu >= 3 Then Zakret = Zakret + 5
           Wend

           Licznik_czasu = 0
           Led_settings = 0
           While Stop_button = Wcisniety
              Do
                 Waitms 10
                 Incr Licznik_czasu
              Loop Until Stop_button = Puszczony
              If Licznik_czasu >= 3 Then Zakret = Zakret - 5
           Wend
        Loop                                               'Until Start_button = Puszczony
     End If

     If Stop_button = Wcisniety Then
        Cls
        Lcd "OstryZ PWM: "
        Do
        Loop Until Start_button = Puszczony
        Do
           Locate 1 , 13
           Lcd Ostry_zakret ; " "
           If Cz5 = Linia Then
              Pwm1a = Max_speed
              Pwm1b = Ostry_zakret
           End If
           If Cz2 = Linia Then
              Pwm1a = Ostry_zakret
              Pwm1b = Max_speed
           End If

           Licznik_czasu = 0
           Led_settings = 0
           While Start_button = Wcisniety
              Do
                 Waitms 10
                 Incr Licznik_czasu
              Loop Until Start_button = Puszczony
              If Licznik_czasu >= 3 Then Ostry_zakret = Ostry_zakret + 5
           Wend

           Licznik_czasu = 0
           Led_settings = 0
           While Stop_button = Wcisniety
              Do
                 Waitms 10
                 Incr Licznik_czasu
                 If Licznik_czasu = 100 Then Led_settings = 1
              Loop Until Stop_button = Puszczony
              If Led_settings = 1 Then Exit Do
              If Licznik_czasu >= 3 Then Ostry_zakret = Ostry_zakret - 5
           Wend
        Loop                                               'Until Stop_button = Puszczony
     End If
'...............................................................................
'Wyświetlanie wartości PWM
'...............................................................................
     Home
     Lcd "PWM1a: " ; Pwm1a ; "       "
     Lowerline
     Lcd "PWM1b: " ; Pwm1b ; "       "
  Loop                                                     'Until Stop_button = Wcisniety
  Pwm1a = 0
  Pwm1b = 0
  Left_motor_przod = Stoi
  Right_motor_przod = Stoi
  Do
     If Start_button = Wcisniety Then
        Waitms 25
        If Start_button = Wcisniety Then Exit Do
     End If
  Loop
Loop
End                                                         'End program

Sensors_settings:                                           'Ustawienia czujników
Cls
Do
  If Cz1 = Tlo And Cz2 = Tlo And Cz3 = Linia And Cz4 = Linia And Cz5 = Tlo And Cz6 = Tlo Then
     Home
     If Linia = 1 Then
        Lcd "Linia biala   "
     Else
        Lcd "Linia czarna  "
     End If
     Lowerline
     If Tlo = 1 Then
        Lcd "Tlo biale     "
     Else
        Lcd "Tlo czarne    "
     End If
     Waitms 500
     Exit Do
  Else
     Toggle Linia
     Toggle Tlo
     Gosub Ustaw_robota_na_linii
  End If
Loop

Home                                                        'Kursor na pozycji 1, 1
Lcd " C2:  C3:  C5:  "
Lowerline
Lcd " C1:  C4:  C6:  "
Do
  If Cz2 = Linia Then
     Locate 1 , 5
     Lcd "1"
  Else
     Locate 1 , 5
     Lcd "0"
  End If
  If Cz3 = Linia Then
     Locate 1 , 10
     Lcd "1"
  Else
     Locate 1 , 10
     Lcd "0"
  End If
  If Cz5 = Linia Then
     Locate 1 , 15
     Lcd "1"
  Else
     Locate 1 , 15
     Lcd "0"
  End If
  If Cz1 = Linia Then
     Locate 2 , 5
     Lcd "1"
  Else
     Locate 2 , 5
     Lcd "0"
  End If
  If Cz4 = Linia Then
     Locate 2 , 10
     Lcd "1"
  Else
     Locate 2 , 10
     Lcd "0"
  End If
  If Cz6 = Linia Then
     Locate 2 , 15
     Lcd "1"
  Else
     Locate 2 , 15
     Lcd "0"
  End If
  If Start_button = Wcisniety Then
     Waitms 25
     If Start_button = Wcisniety Then Exit Do
  End If
Loop
Do
Loop Until Start_button = Puszczony
Return

Ustaw_robota_na_linii:
Lcd "  Ustaw robota  "
Lowerline
Lcd "    na linii    "
Return

Speed_settings:
Cls
Lcd "Maks. predkosc:  "
Do
  'Wszystkie ON
  If Speed_button_1 = Wcisniety And Speed_button_2 = Wcisniety And Speed_button_3 = Wcisniety Then Max_speed = 255
  'Dwa ON
  If Speed_button_1 = Wcisniety And Speed_button_2 = Wcisniety And Speed_button_3 = Puszczony Then Max_speed = 200
  If Speed_button_1 = Wcisniety And Speed_button_2 = Puszczony And Speed_button_3 = Wcisniety Then Max_speed = 200
  If Speed_button_1 = Puszczony And Speed_button_2 = Wcisniety And Speed_button_3 = Wcisniety Then Max_speed = 200
  'Jeden ON
  If Speed_button_1 = Wcisniety And Speed_button_2 = Puszczony And Speed_button_3 = Puszczony Then Max_speed = 150
  If Speed_button_1 = Puszczony And Speed_button_2 = Puszczony And Speed_button_3 = Wcisniety Then Max_speed = 150
  If Speed_button_1 = Puszczony And Speed_button_2 = Wcisniety And Speed_button_3 = Puszczony Then Max_speed = 150
  'Wszystkie OFF
  If Speed_button_1 = Puszczony And Speed_button_2 = Puszczony And Speed_button_3 = Puszczony Then Max_speed = 100
  If Speed_button_1 = Puszczony And Speed_button_2 = Puszczony And Speed_button_3 = Puszczony Then Max_speed = 100
  If Speed_button_1 = Puszczony And Speed_button_2 = Puszczony And Speed_button_3 = Puszczony Then Max_speed = 100
  Locate 2 , 8
  If Max_speed = 255 Then Lcd "100%"
  If Max_speed = 200 Then Lcd "80% "
  If Max_speed = 150 Then Lcd "60% "
  If Max_speed = 100 Then Lcd "40% "
  Pwm1a = Max_speed
  Pwm1b = Max_speed

Zakret = 177
Ostry_zakret = 0
  If Start_button = Wcisniety Then
     Waitms 25
     If Start_button = Wcisniety Then Exit Do
  End If
Loop
Do
Loop Until Start_button = Puszczony
Gosub Eliminacja_drgan
Return

Eliminacja_drgan:
  Waitms 20
Return

Czas_cofania:
  Waitms 150
Return

Prosto:
  Pwm1a = Max_speed
  Pwm1b = Max_speed
Return

Lekko_w_prawo:
  If Cz1 = Linia Then Skret_p(1) = 1 Else Skret_p(1) = 0
  If Cz2 = Linia Then Skret_p(2) = 1 Else Skret_p(2) = 0
  If Cz3 = Linia Then Skret_p(3) = 1 Else Skret_p(3) = 0
  If Cz4 = Linia Then Skret_p(4) = 1 Else Skret_p(4) = 0
  If Cz5 = Linia Then Skret_p(5) = 1 Else Skret_p(5) = 0
  If Cz6 = Linia Then Skret_p(6) = 1 Else Skret_p(6) = 0
  Pwm1a = Max_speed
  Pwm1b = Zakret
  Prawy_ostry_ostatni = 0
  Lewy_ostry_ostatni = 0
  Prawy_ostatni = 1
  Lewy_ostatni = 0
Return

Lekko_w_lewo:
  If Cz1 = Linia Then Skret_l(1) = 1 Else Skret_l(1) = 0
  If Cz2 = Linia Then Skret_l(2) = 1 Else Skret_l(2) = 0
  If Cz3 = Linia Then Skret_l(3) = 1 Else Skret_l(3) = 0
  If Cz4 = Linia Then Skret_l(4) = 1 Else Skret_l(4) = 0
  If Cz5 = Linia Then Skret_l(5) = 1 Else Skret_l(5) = 0
  If Cz6 = Linia Then Skret_l(6) = 1 Else Skret_l(6) = 0
  Pwm1a = Zakret
  Pwm1b = Max_speed
  Prawy_ostry_ostatni = 0
  Lewy_ostry_ostatni = 0
  Prawy_ostatni = 0
  Lewy_ostatni = 1
Return

Ostro_w_prawo:
  Pwm1a = Max_speed
  Pwm1b = Max_speed
  Right_motor_przod = Stoi
  Waitms 15
  Right_motor_tyl = Jedzie
  Do
  Loop Until Cz3 = Linia Or Cz5 = Linia
  Right_motor_tyl = Stoi
  Waitms 15
  Right_motor_przod = Jedzie

  Prawy_ostry_ostatni = 1
  Lewy_ostry_ostatni = 0
  Prawy_ostatni = 0
  Lewy_ostatni = 0
Return
Ostro_w_lewo:
  Pwm1a = Max_speed
  Pwm1b = Max_speed
  Left_motor_przod = Stoi
  Waitms 15
  Left_motor_tyl = Jedzie
  Do
  Loop Until Cz3 = Linia Or Cz2 = Linia
  Left_motor_tyl = Stoi
  Waitms 15
  Left_motor_przod = Jedzie
  Prawy_ostry_ostatni = 0
  Lewy_ostry_ostatni = 1
  Prawy_ostatni = 0
  Lewy_ostatni = 0
Return

Zawracanie_w_prawo:
  Pwm1a = Max_speed
  Pwm1b = Max_speed
  Right_motor_przod = Stoi
  Waitms 15
  Right_motor_tyl = Jedzie
  Do
  Loop Until Cz3 = Linia Or Cz5 = Linia
  Right_motor_tyl = Stoi
  Waitms 15
  Right_motor_przod = Jedzie

  Prawy_ostry_ostatni = 1
  Lewy_ostry_ostatni = 0
  Prawy_ostatni = 0
  Lewy_ostatni = 0
Return

Zawracanie_w_lewo:
  Pwm1a = Max_speed
  Pwm1b = Max_speed
  Left_motor_przod = Stoi
  Waitms 15
  Left_motor_tyl = Jedzie
  Do
  Loop Until Cz3 = Linia Or Cz2 = Linia
  Left_motor_tyl = Stoi
  Waitms 15
  Left_motor_przod = Jedzie
  Prawy_ostry_ostatni = 0
  Lewy_ostry_ostatni = 1
  Prawy_ostatni = 0
  Lewy_ostatni = 0
Return

Program był pisany 3 dni. Przejazdy robota na zawodach to maksimum jego możliwości. Przy większej prędkości robot wylatuje z trasy ze względu na jego ogromną masę.

Jeśli coś pominąłem/czegoś brakuje to proszę o info na PW.

Chętnie odpowiem na wszelkie pytania.

__________

Komentarz dodany przez: Treker

Publikacja dopiero po dodaniu zdjęcia jako załącznik.

Przydałby się również większy wstęp, który będzie widoczny na portalu oraz w katalogu 🙂

follow the line.sch

czujnikrobot v2.0.brd

IMG_9029.thumb.JPG.c3d04e1a4afe7d4ef7b6bc386db6fdbf.JPG

IzyboT.brd

  • Lubię! 8
Link do komentarza
Share on other sites

Podoba Ci się ten projekt? Zostaw pozytywny komentarz i daj znać autorowi, że zbudował coś fajnego!

Masz uwagi? Napisz kulturalnie co warto zmienić. Doceń pracę autora nad konstrukcją oraz opisem.

bartek1333 Stały bywalec

bartek1333

Pozostałe pliki się normalnie otwierają, tylko z tym jest problem.

Bład wyskakuje mniej więcej taki: Invalid data in file ( i ścieżka pliku).

Więc to raczej nie dotyczy wersji Eagle.

Link do komentarza
Share on other sites
Polecacz

Polecacz 101

Zarejestruj się lub zaloguj, aby ukryć tę reklamę.
Zarejestruj się lub zaloguj, aby ukryć tę reklamę.

jlcpcb.jpg

jlcpcb.jpg

Produkcja i montaż PCB - wybierz sprawdzone PCBWay!
   • Darmowe płytki dla studentów i projektów non-profit
   • Tylko 5$ za 10 prototypów PCB w 24 godziny
   • Usługa projektowania PCB na zlecenie
   • Montaż PCB od 30$ + bezpłatna dostawa i szablony
   • Darmowe narzędzie do podglądu plików Gerber
Zobacz również » Film z fabryki PCBWay

rafi92 Aktywny debiutant

rafi92

Witam takze mam problem z otwarciem tego pliku

Udało mi się rozwiązać problem.

Starczyło ściągnąć najnowszą wersje eagla(v 6) wcześniej korzystałem z 5 i ona nie chciała tego otworzyć.

Link do komentarza
Share on other sites
bartek1333 Stały bywalec

bartek1333

OK teraz ładnie chodzi.

To teraz pytanie dot. płytki. Napisałeś, że sam robiłeś płytkę termotransferem. A w jaki sposób robiłeś przelotki?

I czy możesz dać dokładniejsze foto przelotek?

Link do komentarza
Share on other sites
ProeXtreme Stały bywalec

ProeXtreme

  • Autor tematu

Przelotki robiłem drutem tzn.:

- wierciłem otwór na przelotkę,
- wkładałem drut do otworu,
- lutowałem jeden koniec drutu do via,
- odcinałem nadmiar drutu,
- lutowałem drugi koniec drutu do drugiej warstwy PCB.

Zabawy trochę było, ale połączenie przelotek jest przynajmniej pewne.

  • Lubię! 2
Link do komentarza
Share on other sites
rafi92 Aktywny debiutant

rafi92

mam pytanie dotyczące pinów SV1,3,4,5 które są z którymi są połączone i w jaki sposób mogę je zastąpić ścieżką.

Domyślam się ze 1 i 3 są połączone razem. a co z 4 i 5??

Link do komentarza
Share on other sites

Dołącz do dyskusji, napisz odpowiedź!

Jeśli masz już konto to zaloguj się teraz, aby opublikować wiadomość jako Ty. Możesz też napisać teraz i zarejestrować się później.
Uwaga: wgrywanie zdjęć i załączników dostępne jest po zalogowaniu!

Anonim
Dołącz do dyskusji! Kliknij i zacznij pisać...

×   Wklejony jako tekst z formatowaniem.   Przywróć formatowanie

  Dozwolonych jest tylko 75 emoji.

×   Twój link będzie automatycznie osadzony.   Wyświetlać jako link

×   Twoja poprzednia zawartość została przywrócona.   Wyczyść edytor

×   Nie możesz wkleić zdjęć bezpośrednio. Prześlij lub wstaw obrazy z adresu URL.

×
 Udostępnij
Przejdź do listy tematów
×
×
  • Utwórz nowe...

Ważne informacje

Ta strona używa ciasteczek (cookies), dzięki którym może działać lepiej. Więcej na ten temat znajdziesz w Polityce Prywatności.

  Rozumiem